; ----------------------------------------
;
; Gordon's Lightroom 2.x Shortcuts
; Updated: Oct-23 2009
; www.night-ray.com
;
; Use numpad to perform certain develop and
; library functions. This effectively disables
; the number pad for digit entry (except 0)
; please use the main keyboard instead.
;
; NOTE: NumLock must be ON for script to work
;
;
; Left/Right    - Prev or Next photo
; Up/Down       - Brightness
; ALT Up/Down   - Exposure
; NumPad 5      - Toggle Dev/Lib Module [new]
; ALT NumPad 5  - Crop Tool [new]
; +/-           - Fill Light
; Page Up/Dn    - Contrast
; ALT PgUp/PgDn - Black Clipping
; Home/End      - Color Temperature
; ALT Home/End  - Recovery
; Div/Mult      - Color Tint
; Enter         - Paste Previous
; ALT Enter     - Sync Settings [new]
; Del           - Auto Tone
; ALT Del       - Auto White Balance [new]
; F5            - Library: render standard sized previews [new]
; Ctrl NumpadX  - Library: Execute a preset, see below [new]
;
;
SetTitleMatchMode,2
;
; *** LIBRARY PRESETS ***
; Change the text just before ComboBox4
;
#IfWinActive, Lightroom - Library
  ^numpad0::	Control ChooseString, Default Settings,   ComboBox4, Lightroom
  ^numpad1::	Control ChooseString, BW Developed,       ComboBox4, Lightroom
  ^numpad2::	Control ChooseString, FX Dream Soft,      ComboBox4, Lightroom
  ^numpad3::	Control ChooseString, FX Dream Strong,    ComboBox4, Lightroom
  ^numpad4::	Control ChooseString, FX Hard,            ComboBox4, Lightroom
  ^numpad5::	Control ChooseString, FX Harder,          ComboBox4, Lightroom
  ^numpad6::	Control ChooseString, Detail Enhancement, ComboBox4, Lightroom
  ^numpad7::	Control ChooseString, FX Cross Green,     ComboBox4, Lightroom
  ^numpad8::	Control ChooseString, FX Cross Warm,      ComboBox4, Lightroom
  ^numpad9::	Control ChooseString, FX Bleach,          ComboBox4, Lightroom
#IfWinActive	
;
;
; *** DEVELOP SHORTCUTS ***
;
#IfWinActive, Lightroom - Develop
  numpad5::     Send ^!1
  !numpad5::    Send r
  numpad4::     Send e,^{Left}
  numpad6::     Send e,^{Right}
  !numpad8::    lrdAdd(09)
  !numpad2::    lrdSub(09)
  numpad8::     lrdAdd(13)
  numpad2::     lrdSub(13)
  NumpadAdd::   lrdAdd(11)
  NumpadSub::   lrdSub(11)
  !Numpad9::    lrdAdd(12)
  !Numpad3::    lrdSub(12)
  !numpad7::    lrdAdd(10)
  !Numpad1::    lrdSub(10)
  numpad9::     lrdAdd(14)
  numpad3::     lrdSub(14)
  numpad7::     lrdAdd(04)
  numpad1::     lrdSub(04)
  NumPadMult::  lrdAdd(05)
  NumPadDiv::   lrdSub(05)
  NumPadDot::   Send ^u
  !NumPadDot::  Send ^+u
  NumPadEnter:: Send ^!v 
  !NumPadEnter::Send ^+s
  ;
  lrdAdd(delta) {
  	instance := lrGetControl( Static, 6, "Treatment :", delta )
  	ControlClick, Static%instance%
  	Send {=}
  }
  ;
  lrdSub(delta) {
  	instance := lrGetControl( Static, 6, "Treatment :", delta )
  	ControlClick, Static%instance%
  	Send {-}
  }
#IfWinActive
;
; *** LIBRARY SHORTCUTS ***
;
#IfWinActive, Lightroom - Library
  numpad5::     Send ^!2
  !numpad5::    Send r
  numpad4::     Send ^{Left}
  numpad6::     Send ^{Right}
  !numpad8::    lrlClick(03)
  !numpad2::    lrlClick(02)
  numpad8::     lrlClick(20)
  numpad2::     lrlClick(17)
  NumpadAdd::   lrlClick(11)
  NumpadSub::   lrlClick(10)
  !numpad9::    lrlClick(15)
  !numpad3::    lrlClick(14)
  !numpad7::    lrlClick(07)
  !numpad1::    lrlClick(06)
  numpad9::     lrlClick(24)
  numpad3::     lrlClick(21)
  numpad7::     lrlClick(-6)
  numpad1::     lrlClick(-7)
  NumPadMult::  lrlClick(-2)
  NumPadDiv::   lrlClick(-3)
  NumPadDot::   Send ^u
  !NumPadDot::  Send ^+u
  NumPadEnter:: Send ^!v 
  !NumPadEnter::Send ^+s
  ;
  F5::
  	SetKeyDelay,200,10
	Send !lvr{space}
	return
  ;
  lrlClick(delta) {
  	instance := lrGetControl( Button, 6, "Auto Tone", delta )
  	ControlSend, Button%instance%, {SPACE}, ahk_class AgWinMainFrame
  }
#IfWinActive
;
; Fetch the Control Instance using Type, Title, and Instance Delta
;
lrGetControl( type, typeLen, title, delta ) {
  global lrLastTitle, lrLastCBase, lrLastCache
  ;
  if (lrLastTitle = title and lrLastCache > A_TickCount )
  {
    ; Cached! Saves time.
    return lrLastCBase + delta
  }
  else
  {
    WinGet, ActiveControlList, ControlList, ahk_class AgWinMainFrame
    Loop, Parse, ActiveControlList, `n
    {
      IfInString, A_LoopField, %type%
      {
        ControlGetText, text, %A_LoopField%
        IfInString, text, %title%
        {
          StringMid, controlbase, A_LoopField, typeLen+1
          lrLastTitle := title
          lrLastCBase := controlbase
          lrLastCache := A_TickCount + (15 * 60000)
          return controlbase + delta
        }
      }
    }
  }
  return 999999
}
;
; NOTE: Control ChooseString, preset name, ComboBox4, Lightroom
; End
; ----------------------------------------